*   cda03a-review3.do - CDA Lab Guide 3: Introduction to Graphs - 23May2007

    capture log close 
    set more off 
    estimates clear 

*   1 open the log
    log using cda03a-review3.log, replace text
    version 9.2
    set scheme s2mono 

*   2 load the data
    use science3, clear

*   3 descriptive plot
    sum mcit3
    dotplot mcit3
    graph export cda03a-review3-fig1.emf, replace

*   4 bivariate plot
    graph bar mcit3, over(female)
      graph export cda03a-review3-fig2.emf, replace
    graph bar (median) mcit3, over(female)
      graph export cda03a-review3-fig2a.emf, replace
    graph bar mcit3, over(female, label(labsize(small))) ///
        over(felclass, label(labsize(small)))
      graph export cda03a-review3-fig3.emf, replace
    graph matrix job phd female
      graph export cda03a-review3-fig4.emf, replace

*   5 advanced plot
    graph twoway scatter job fel, ///
        ylabel(1(1)5, grid) yscale(range(1 5)) ytitle("Job Prestige") ///
        xlab(1(1)5, grid) xscale(range(1 5)) xtitle("Fel|PhD. Prestige")
    graph export cda03a-review3-fig5.emf, replace

*   6 more advanced plot
    logit faculty female fel, nolog
    prgen fel, from(-10) to(10) generate(women) x(female=1) rest(mean)
    label var womenp1 "Pr(Faculty|Female)"
    prgen fel, from(-10) to(10) generate(men) x(female=0) rest(mean)
    label var menp1 "Pr(Faculty|Male)"

    scatter womenp1 womenx, ///
        ylabel(0(.25)1., grid) ytitle("Pr(Faculty)") ///
        xlabel(-10(5)10) xtitle("Fel|PhD Prestige") ///
        msymbol(Sh) connect(l) xline(-10 -5 0 5 10) ///
     || scatter menp1 womenx, msymbol(Th) connect(l)
    graph export cda03a-review3-fig6.emf, replace

    scatter womenp1 menp1 womenx, ///
        ylabel(0(.25)1., grid) ytitle("Pr(Faculty)") ///
        xlabel(-10(5)10) xtitle("Fel|PhD Prestige") ///
        msymbol(Sh Th) connect(l l) clpattern(solid solid) ///
        legend(lab(1 "Pr(UnivFaculty|Female)") lab(2 "Pr(UnivFaculty|Male)"))
      graph export cda03a-review3-fig6a.emf, replace

*   7 close log file
    log close
    exit