*   cda04a-review4.do - CDA Lab Guide 4: Models for Binary Outcomes - 23May2007

    capture log close 
    set more off 
    estimates clear 

*   1 open the log
    log using cda04a-review4.log, replace text
    version 9.2
    set scheme s2mono 

*   2 load the data
    use sci-review, clear

*   3 extract a subset
    tab female
    drop if female==1
    sum female isfac fellow phd mcit3 mnas
    drop if isfac>=. | mcit3>=. | mnas>=.
    sum isfac fellow phd mcit3 mnas

*   4 save the subset as a new file
    save sci-male, replace

*   5 binary probit model
    probit isfac fellow phd mcit3 mnas

*   6 standardized coefficients
    listcoef, help

*   7 predict probabilities for observations
    predict prprobit
      label var prprobit "Probit: Predicted Probability"
    sum prprobit
    dotplot prprobit
    graph export cda04a-review4-fig1.emf, replace

*   8 predict specific probabilities
    prvalue , x(fellow=1 phd=4 mnas=1) rest(mean)

*   9 marginal and discrete change
    prchange, rest(mean) help

*   10 binary logit model
    logit isfac fellow phd mcit3 mnas, nolog

*   11 list odds ratios
    listcoef, help

*   12 close log file
    log close
    exit