*   cda06a-review6.do - CDA Lab Guide 6: Models for Ordinal Outcomes - 23May2007

    capture log close 
    set more off 
    estimates clear 

*   1 open the log
    log using cda06a-review6.log, replace text
    version 9.2
    set scheme s2mono 

*   2 load and clean the data
    use sci-review, clear
    keep jobprst pub1 phd female
    tab1 jobprst pub1 phd female, m
    drop if jobprst>=. | pub1>=. | phd>=. | female>=.
    sum

*   3 ordered probit and ordered logit
    oprobit jobprst pub1 phd female, nolog
    ologit  jobprst pub1 phd female, nolog

*   4 standardized coefficients
    listcoef, help

*   5 predict probabilities in sample
    predict lpad lpgo lpst lpdi
    label var lpad "OLM Pr(Adeq)"
    label var lpgo "OLM Pr(Good)"
    label var lpst "OLM Pr(Strg)"
    label var lpdi "OLM Pr(Dist)"
    sum lpad lpgo lpst lpdi

*   6 plot probabilities
    prgen pub1, x(female=1 phd=4) rest(mean) from(0) to(10) gen(pubpr)
    label var pubprp1 "Pr(Adeq)"
    label var pubprp2 "Pr(Good)"
    label var pubprp3 "Pr(Strg)"
    label var pubprp4 "Pr(Dist)"
    label var pubprs1 "Pr(<=Adeq)"
    label var pubprs2 "Pr(<=Good)"
    label var pubprs3 "Pr(<=Strg)"
    label var pubprs4 "Pr(<=Dist)"

    scatter pubprp1 pubprx, ///
        ylabel(0(.25).75, grid) yscale(range(0 .75)) ///
        ytitle("Pr(InSpecificRank)") xlabel(0(2.5)10) ///
        connect(l) msymbol(Oh) ///
     || scatter pubprp2 pubprx, connect(l) msymbol(Dh) ///
     || scatter pubprp3 pubprx, connect(l) msymbol(Th) ///
     || scatter pubprp4 pubprx, connect(l) msymbol(Sh)
    graph export cda06a-review6-fig1.emf, replace

    scatter pubprs1 pubprx, ///
        ylabel(0(.25)1., grid) yscale(range(0 1)) ///
        ytitle("Pr(jobprst<=rank)") xlabel(0(2.5)10) ///
        connect(l) msymbol(Oh) ///
     || scatter pubprs2 pubprx, connect(l) msymbol(Dh) ///
     || scatter pubprs3 pubprx, connect(l) msymbol(Th) ///
     || scatter pubprs4 pubprx, connect(l) msymbol(Sh)
    graph export cda06a-review6-fig2.emf, replace

*   7 predict specific probabilities
    quietly ologit jobprst pub1 phd female
    prvalue, x(female=1 pub1=0) rest(mean)
    prvalue, x(female=0 pub1=0) rest(mean)

*   8 compute marginal and discrete change
    quietly ologit jobprst pub1 phd female
    prchange, rest(mean)

*   9 odds ratios
    listcoef, help

*   10 test the parallel regressions assumption
    ologit jobprst pub1 phd female
    brant, detail

*   11 close up
    log close
    exit