capture log close
    log using cda00-getting-started.log , text replace

//  pgm:        cda00-getting-started.do
//  task:       your task
//  project:    your project 
//  author:     your name
//  date:       today's date

*   1 setup
    version 10
    set linesize 80
    clear all
    macro drop _all

*   2 open data
    use science3, clear

*   3 look
    codebook , compact

*   4 recode work into dummy
    gen isfac = (work==1) if (work<.)

*   5 add variable and value labels
    label variable isfac "1=Faculty in University"
    label define isfacfmt 0 "0_NotFac" 1 "1_Faculty"
    label values isfac isfacfmt

*   6 verify transformation
    tab work isfac , m

*   7 create ordinal from continuous phd
*   a) generate
    gen phdcat=phd
    recode phdcat .=. 1/1.99=1 2/2.99=2 3/3.99=3 4/5=4
*   b) label
    label variable phdcat "Rankings of University Job."
    label define phdcatfmt 1 "1_Adeq" 2 "2_Good" 3 "3_Strg" 4 "4_Dist"
    label values phdcat phdcatfmt
*   c) verify
    tab phd phdcat

*   8 reduce variables
    keep pub1 phd phdcat enrol isfac

*   9 listwise deletion of missing values
*   a) create new variable & markout missing
    mark nomiss
    markout nomiss pub1 phd phdcat enrol isfac 
*   b) check how many are missing
    tab nomiss
*   c) keep only nonmissing
    keep if nomiss==1

*   10 save
    save sci-temp, replace 

*   11 close log and exit
    log close
    exit