capture log close
set matsize 500
set more off
log using rm4ch5, text replace

***
*** RM4CLDV Ch 5: Ordinal Outcomes - using SPost - verified 3/9/01
***

*** Page 126: Table 5.1
use ordwarm2,clear
summarize

*** Page 127: Table 5.2 - LRM column
regress warm yr89 male white age ed prst

*** Page 127: Table 5.2 - Ordered Logit (OLM)
ologit warm yr89 male white age ed prst, nolog

*** Page 127: Table 5.2 - Ordered Probit (OPM)
oprobit warm yr89 male white age ed prst, nolog
** alternative parameters
* intercept
lincom 0 - _b[_cut1]
* cutpoint 1 is 0
* cutpoint 2
lincom _b[_cut2] - _b[_cut1]
* cutpoint 3
lincom _b[_cut3] - _b[_cut1]

*** Page 129: Table 5.3 - Standardized coefficients for OPM
listcoef, std help

*** Page 129: Table 5.3 - Standardized coefficients for OLM
quietly ologit warm yr89 male white age ed prst, nolog
listcoef, std help

*** Predicated probabilities for OLM
predict lpsd lpd lpa lpsa
label var lpsd "OLM Pr(SD)"
label var lpd"OLM Pr(D)"
label var lpa"OLM Pr(A)"
label var lpsa "OLM Pr(SA)"

*** Page 131: Table 5.4 - predicated probabilities within sample
sum lpsd lpd lpa lpsa

*** Predicated probabilities for OPM
predict ppsd ppd ppa ppsa
label var ppsd "OPM Pr(SD)"
label var ppd"OPM Pr(D)"
label var ppa"OPM Pr(A)"
label var ppsa "OPM Pr(SA)"

*** Page 131: Range of predicted probabilities
sum lpsd lpd lpa lpsa ppsd ppd ppa ppsa

*** Page 132: Figure 5.3 - Predicted and cumulative probabilities
prgen age, x(male 0 yr89 1) rest(mean) f(20) t(80) gen(w89) n(13)

** Predicted probabilities:
set textsize 125
label var w89p1 "Strongly Agree"
label var w89p2 "Agree"
label var w89p3 "Disagree"
label var w89p4 "Strongly Disagree"
#delimit ;
graph w89p1 w89p2 w89p3 w89p4 w89x,
title("Predicted Probabilities for Women in 1989")
b2("Age") l2("Predicted Probability") gap(3)
xlabel(20,40,60,80) ylabel(0,.25,.50) xscale(20,80) yscale(0,.5)
connect(ssss) s(OdST) noaxis yline(0,.5);
#delimit cr
translate @Graph rm4ch5fig3a.wmf, replace

** Cumulative probabilities:
set textsize 125
label var w89s1 "Strongly Agree"
label var w89s2 "Agree"
label var w89s3 "Disagree"
label var w89s4 "Strongly Disagree"
#delimit ;
graph w89s1 w89s2 w89s3 w89s4 w89x,
title("Cumulative Probabilities for Women in 1989")
b2("Age") l2("Predicted Probability") gap(3)
xlabel(20,40,60,80) ylabel(0,.25,.50,.75,1.0) xscale(20,80) yscale(0,1)
connect(sss) yline(0,1) s(OdS.) noaxis;
#delimit cr
translate @Graph rm4ch5fig3b.wmf, replace

*** Page 134: Table 5.5 - predicated probabilities from OLM
use ordwarm2,clear
ologit warm yr89 male white age ed prst, nolog
prtab yr89 male, rest(mean) novar

*** Page 135: Table 5.6 - OLM marginals for women in 1989
prchange, x(male 0 yr89 1) rest(mean)

*** Page 137: Table 5.7 - discrete change at mean for OLM
prchange, rest(mean)

*** Page 142: Table 5.8 - binary logits on cumulative counts
ologit warm yr89 male white age ed prst, nolog
listcoef, factor help
** binary logit on 1=SD, 0=D&A&SA
logit warmlt2 yr89 male white age ed prst, nolog
** binary logit on 1=SD&D, 0=A&SA
logit warmlt3 yr89 male white age ed prst, nolog
** binary logit on 1=SD&D&A, 0=SA
logit warmlt4 yr89 male white age ed prst, nolog

*** Page 142: Table 5.9 - Brant test of parallel regressions
quietly ologit warm yr89 male white age ed prst, nolog
brant
** approximate LR test of parallel regressions
omodel logit warm yr89 male white age ed prst

log close