capture log close
set matsize 500
set more off
log using rm4ch6, text replace

***
*** RM4CLDV Ch 6: Nominal Outcomes - using SPost - verified 3/9/01
***

*** Page 152: Table 6.1
use nomocc2,clear
summarize
tab occ

*** Page 159: Table 6.2 - with menial as reference group
mlogit occ white ed exper, basecategory(1) nolog

*** Page 162: Table 6.3
** LR tests
mlogtest, lr
** Wald tests
mlogtest, wald

** Estimate with white collar as the base category
mlogit occ white ed exper,basecategory(4) nolog

*** Page 163: Test that two outcomes can be combined
** Wald Test based on multinomial loghit:
mlogtest, combine
** LR Test based on binary logit:
gen occ45 = occ - 4
tab occ45
logit occ45 white ed exper if occ45>=0, nolog

*** Page 165: Predicted (not plotted in book)
quietly mlogit occ white ed exper
prgen ed, rest(mean) f(1) t(20) gen(mn)
graph mnp1 mnp2 mnp3 mnp4 mnp5 mnx, c(ssss)
translate @Graph rm4ch6ed.wmf, replace

*** Page 167: Table 6.4 - Discrete and Partial Changes
prchange

*** Page 168: Figure 6.1 - Discrete Change Plot
** -mlogview- can be used interactively to create this plot
mlogplot white ed exper, dc std(0ss) p(.1) min(-.25) max(.50) ntics(7)
translate @Graph rm4ch6fig1.wmf, replace

*** Page 170: Table 6.5 - Factor Changes
listcoef, factor help

*** Page 175: Figure 6.4 - Odds Ratio Plot
** -mlogview- can be used interactively to create this plot
mlogplot white ed exper, or std(0ss) p(.1) min(-2.75) max(.55) ntics(7)
translate @Graph rm4ch6fig4.wmf, replace

*** Page 176: Figure 6.5 - Odds Ratio Plot with Discrete Change
** -mlogview- can be used interactively to create this plot
mlogplot white ed exper, or dc std(0ss) p(.1) min(-2.75) max(.55) ntics(7)
translate @Graph rm4ch6fig5.wmf, replace

*** Page 178: Figure 6.6 - Odds Ratio Plot with Discrete Change
use ordwarm2, clear
label def lw 1 1SD 2 2D 3 3A 4 4SA
label val warm lw
mlogit warm-prst, nolog
prchange
mlogplot yr89 male age ed, or dc std(00ss) b(1) p(.1) /*
*/ min(-1.5) max(1.5) ntics(7)
translate @Graph rm4ch6fig6.wmf, replace

*** Page 184: IIA
use nomocc2, clear
quietly mlogit occ white ed exper
* results for SH test will differ each time due to use of random seed
mlogtest, iia

log close